Bookmark and Share

Notice: On April 23, 2014, Statalist moved from an email list to a forum, based at statalist.org.


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: logit model with endogenous


From   John Antonakis <[email protected]>
To   [email protected]
Subject   Re: st: logit model with endogenous
Date   Tue, 25 Mar 2014 09:42:44 +0100

[I don't think that this went through on the first send--resending]

Hi Richard:

-gsem- does not allow an explicit correlation of disturbances; thus, if the mediator is endogenous, the estimator will not be consistent. Thus, one is better off using ivprobit or cmp (from SSC). With gsem one would have to do a couple of tricks to get going as an instrumental-variable estimator. Here is a work-around that Stata's tech support gave me when I pinged them on this question, which I used to do with MPlus but had trouble doing it when using Stata. The solution is quite straight forward and includes modeling an extra latent variable, "L":

  cmp setup
  webuse laborsup, clear
  replace fem_inc = fem_inc - 10
  cmp (fem_work =  fem_educ kids) ///
      (other_inc = fem_work fem_educ kids male_educ), ///
      ind($cmp_probit $cmp_cont)

  gsem (fem_work <- fem_educ kids L@1, probit) ///
       (other_inc <- fem_work fem_educ kids male_educ L), var(L@1)

  /* Coefficients in the other_inc equation match */
  /* Probit assumes an error variance of 1, but we have added
   *    and extra variance of 1 from L. */
  /* To obtain probit coefficients, we can divide by the
   *    square root of 2 */

  nlcom (fem_educ : _b[fem_work:fem_educ] / sqrt(2)) ///
        (kids : _b[fem_work:kids] / sqrt(2)) ///
        (cons : _b[fem_work:_cons] / sqrt(2))

  /*  We also need to back transform results in order to obtain sigma and
   *  rho that are reported by -cmp-. */

  nlcom (sig: sqrt(_b[var(e.other_inc):_cons] +_b[other_inc:L]^2)) ///
        (rho: _b[other_inc:L]/(sqrt(2)*sqrt(_b[var(e.other_inc):_cons] ///
      + _b[other_inc:L]^2)))

Best,
J.

__________________________________________

John Antonakis
Professor of Organizational Behavior
Director, Ph.D. Program in Management

Faculty of Business and Economics
University of Lausanne
Internef #618
CH-1015 Lausanne-Dorigny
Switzerland
Tel ++41 (0)21 692-3438
Fax ++41 (0)21 692-3305
http://www.hec.unil.ch/people/jantonakis

Associate Editor:
The Leadership Quarterly
Organizational Research Methods
__________________________________________

On 24.03.2014 02:04, Richard Williams wrote:
> Unclear. Do you mean you tried ivprobit, and it would not run? Or are
> you saying you don't think ivprobit is appropriate? If the former,
> show us the code and error messages. If the latter, explain what you
> have against using probit instead. I think it is rare that some great
> (or even small) harm would come from running a probit rather than a
> logit.
>
> I haven't tried it, but i wonder if you could do something like an
> ivlogit model using -gsem-.
>
> At 06:28 PM 3/23/2014, maggie zhang wrote:
>> Hi,
>>
>> I need to run logit model with endogenous covariates. There is only
>> ivprobit/ivtobit in stata. However, I could not run the probit
>> regression for my model instead of the logit. What could I do?
>>
>> Thanks,
>> Best,/Maggie
>> *
>> *   For searches and help try:
>> *   http://www.stata.com/help.cgi?search
>> *   http://www.stata.com/support/faqs/resources/statalist-faq/
>> *   http://www.ats.ucla.edu/stat/stata/
>
> -------------------------------------------
> Richard Williams, Notre Dame Dept of Sociology
> OFFICE: (574)631-6668, (574)631-6463
> HOME:   (574)289-5227
> EMAIL:  [email protected]
> WWW:    http://www.nd.edu/~rwilliam
>
> *
> *   For searches and help try:
> *   http://www.stata.com/help.cgi?search
> *   http://www.stata.com/support/faqs/resources/statalist-faq/
> *   http://www.ats.ucla.edu/stat/stata/


*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/


© Copyright 1996–2018 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   Site index