Bookmark and Share

Notice: On April 23, 2014, Statalist moved from an email list to a forum, based at statalist.org.


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: table formatting in stata


From   Sergiy Radyakin <[email protected]>
To   "[email protected]" <[email protected]>
Subject   Re: st: table formatting in stata
Date   Thu, 6 Jun 2013 18:38:57 -0400

How about this? Sergiy

sysuse auto, clear

local vars "price length weight headroom"
local gvar "foreign"


local n=`:word count `vars''
matrix R=J(`n',7,.)
matrix list R

forval i=1/`n' {
  local w `:word `i' of `vars''
  quietly ttest `w', by(`gvar')
  matrix R[`i',1]=r(N_1)
  matrix R[`i',2]=r(mu_1)
  matrix R[`i',3]=r(sd_1)
  matrix R[`i',4]=r(N_2)
  matrix R[`i',5]=r(mu_2)
  matrix R[`i',6]=r(sd_2)
  matrix R[`i',7]=r(p)
}

matrix coleq R = " " "Group 1" " " " " "Group 2" " " " "
matrix colnames R = N mean SD N mean SD p
matrix rownames R = `vars'

matrix list R , format(%4.3f)

On Thu, Jun 6, 2013 at 6:18 PM, Haluk Vahaboglu <[email protected]> wrote:
> Sergiy,
> Thank you for your contribution.
> Unfortunately, tabstat do not generate a "p" value of T Test. I need n mean sd & "p" on a line.
> Therefore, neither tabstat not tabstatmat resolve this problem.
>
>
> Prof. Dr. Haluk Vahaboğlu
> Istanbul Medeniyet
> Üniversitesi,
> Göztepe Eğitim ve Araştırma Hastanesi
> Enfeksiyon Hastalıkları
> ve Klinik Mikrobiyoloji ABD
> Dr. Erkin Caddesi 34730
> Kadıköy / Istanbul TURKIYE
>
>
>
>
> ----------------------------------------
>> Date: Thu, 6 Jun 2013 16:13:32 -0400
>> Subject: Re: st: table formatting in stata
>> From: [email protected]
>> To: [email protected]
>>
>> Yes, it is possible:
>>
>> sysuse auto,clear
>> tabtstat price weight length, stats(mean sd)
>>
>> If you need it transposed, (and I assume you do) then add an option
>> save to the above, then use Austin Nichols' -tabstatmat- to put
>> results into matrix and transpose it. Type:
>>
>> findit tabstatmat
>>
>> and follow instructions.
>>
>> Best, Sergiy
>>
>>
>> On Thu, Jun 6, 2013 at 5:11 AM, Haluk Vahaboglu <[email protected]> wrote:
>>> TD P { margin-bottom: 0in; }P { margin-bottom: 0.08in; }
>>>
>>>
>>> Hello Everybody,
>>> In our research papers we
>>> mostly present continuous data in a table with comparison to cases vs
>>> controls as "n mean SD and p (from Ttest)". Here is a brief
>>> example of such a table:
>>>
>>>
>>>
>>> ................Cases / Controls
>>> ........N mean (SD) N mean (SD)...p
>>> Var1
>>> Var2
>>>
>>>
>>>
>>> With STATA I use these
>>> commands
>>>
>>>
>>>
>>> 1. "estpost tabstat age
>>> VAR1 VAR2, by(C/C) s(n mean sd) c(s)"
>>> 2. "esttab ., main(mean)
>>> aux(sd) unstack noobs nonote wide compress label"
>>> 3. "estpost ttest age
>>> VAR1 VAR2, by(C/C) une w"
>>> 4. "esttab ., cell("p
>>> (fmt(3))")"
>>>
>>>
>>>
>>> and get two separate
>>> tables "n mean SD" in one and "p" in the other. I afterwards
>>> combine these two in one table formatted as mentioned above.
>>>
>>>
>>>
>>> Is there any simple way to
>>> get a table with n-mean-SD-p all in one line for multiple continuous
>>> variables?
>>> Thanks again
>>> note: sorry for the subject line of my previous message
>>>
>>> *
>>> * For searches and help try:
>>> * http://www.stata.com/help.cgi?search
>>> * http://www.stata.com/support/faqs/resources/statalist-faq/
>>> * http://www.ats.ucla.edu/stat/stata/
>>
>> *
>> * For searches and help try:
>> * http://www.stata.com/help.cgi?search
>> * http://www.stata.com/support/faqs/resources/statalist-faq/
>> * http://www.ats.ucla.edu/stat/stata/
>
> *
> *   For searches and help try:
> *   http://www.stata.com/help.cgi?search
> *   http://www.stata.com/support/faqs/resources/statalist-faq/
> *   http://www.ats.ucla.edu/stat/stata/

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/


© Copyright 1996–2018 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   Site index