Bookmark and Share

Notice: On April 23, 2014, Statalist moved from an email list to a forum, based at statalist.org.


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: OLS assumptions not met: transformation, gls, or glm as solutions?


From   Maarten Buis <[email protected]>
To   [email protected]
Subject   Re: st: OLS assumptions not met: transformation, gls, or glm as solutions?
Date   Wed, 2 Jan 2013 12:05:17 +0100

On Fri, Dec 21, 2012 at 1:33 AM, Alan Acock <[email protected]> wrote:
> If I run
>
> regress qual_p conf_p i.sexrare ston_p forg_p sacr_p
>
> were all variables but for sexrare are proportion of the maximum possible value, the interpretations are simple. A change in conf_p of one percentage point predicts a xx(coefficient) percentage point change in the outcome.
>
> When I run
>
> glm qual_p conf_p i.sexrare ston_p forg_p sacr_p, ///
>  family(binomial) link(logit) vce(robust)
>
> is there a clear interpretation of the coefficient or some transformation of the coefficients?
>
> I'm think the answer should be obvious to me, but it is not.

The exponentiated coefficients have an interpretation that in the
helpfile of -betafit- (available from SSC) we called relative
proportion ratios. In that helpfile we also included an explanation of
it. In the example below I apply this to the fractional logit. It is
easiest to start with the baseline relative proportion: For a city
governed by a majority left wing government with a fairly average
priced houses (a proxy for wealth) and population density (a proxy for
urbanicity) we expect the city to spent about 11 cents on governing
itself (wages of civil servants, maintaining office space for them,
etc.) for every euro spent on everything else. This ratio decreases by
(1-.85)*100%=-15% if the city is governed by a majority right
government, but is virtually the same as the ratio for a completely
right government. The ratio of expenditure on government and
expenditure on everything else tends to be about 40% higher in cities
where the average house price is a 1000 euro higher.

*------------------ begin example ------------------
// get and prepare some data
use "http://fmwww.bc.edu/repec/bocode/c/citybudget.dta";, clear
gen leftright = minorityleft + 2*noleft
label variable leftright ///
      "political orientation of members of city government"
label define leftright 0 "majority left"  ///
                       1 "majority right" ///
                       2 "only right"
label value leftright leftright

gen chouseval = houseval - 1.5
label variable chouseval ///
"average value of a house in 100,000 euros (centered at 150.000 eureo)"
gen cpopdens = popdens - .75
label variable cpopdens ///
"population density in 1000s persons per km^2 (centered at 750 persons
per km^2)"
			
// estimate the model			
glm governing i.leftright chouseval cpopdens, ///
    family(binomial) link(logit) vce(robust) eform
*------------------- end example -------------------
* (For more on examples I sent to the Statalist see:
* http://www.maartenbuis.nl/example_faq )

Hope this helps,
Maarten

---------------------------------
Maarten L. Buis
WZB
Reichpietschufer 50
10785 Berlin
Germany

http://www.maartenbuis.nl
---------------------------------
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/faqs/resources/statalist-faq/
*   http://www.ats.ucla.edu/stat/stata/


© Copyright 1996–2018 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   Site index