Bookmark and Share

Notice: On April 23, 2014, Statalist moved from an email list to a forum, based at statalist.org.


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: St: z transformation - mibeta command


From   Maarten Buis <[email protected]>
To   [email protected]
Subject   Re: st: St: z transformation - mibeta command
Date   Tue, 24 Apr 2012 10:48:15 +0200

--- On Tue, Apr 24, 2012 at 10:04 AM, Hoang Dinh Quoc wrote:
> I am looking for z transformation and mibeta command is supposed to create
> it but when I run this command it always reports no imputations.

As we said before, -mibeta- is only applicable when you have multiple
imputed data. Since you do not have that, you can not use -mibeta-.

If you are doing a simple linear regression, you can just add the
-beta- option to -regress-. Alternativly you can create your
z-standardized variables first and than use -regress- with these
standardized variables without the -beta- option. If you have done so
correctly than you will get exactly the same results. You can compute
the z-standardized values manually: z = (x - mean) / sd, or use Ben
Jann's -center- command, see: -ssc desc center-.

*------------------ begin example ---------------------
sysuse auto, clear

gen byte touse = !missing(price, headroom, weight, turn)

// we can use the -beta- option:
reg price headroom weight turn, beta

// we can estimate this manually:
foreach var of varlist price headroom weight turn {
	sum `var' if touse
	gen double z_`var' = (`var' - r(mean)) / r(sd)
}
reg z_price z_headroom z_weight z_turn

// we can use -center-
center price headroom weight turn if touse, double standardize
reg c_price c_headroom c_weight c_turn
*------------------- end example ----------------------

Possible problems occur when you have binary, categorical, or ordinal
variables. In those cases the z-transformation just does not make
sense.

Hope this helps,
Maarten

--------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany


http://www.maartenbuis.nl
--------------------------
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/


© Copyright 1996–2018 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   Site index