RE: st: RE: twoway graph legend

[Nick Cox <n.j.cox@durham.ac.uk>]

You could do something like this: 

sysuse auto, clear
regr mpg weight i.foreign
predict predict
separate predict, by(foreign) veryshortlabel
line predict? weight, sort

If you want the fits to be different, you are going to have to produce them separately and then combine them, I believe. 

drop predict?

forval i = 0/1 {
	qui regress mpg weight if foreign == `i'
	predict predict`i' if foreign == `i' 
	label var predict`i' "`: label (foreign) `i''" 
}

line predict? weight, sort ytitle("`: var label mpg'") 

Nick 
n.j.cox@durham.ac.uk 

Nikolaos Pandis
 
Many thanks, it looks great.
Could I somehow use -lfit- to get the fitted lines only?
 
From: Nick Cox <n.j.cox@durham.ac.uk>

Try 

separate moment, by(brackettype) veryshortlabel
line moment? rotation 

and see -help separate- 

and see 

SJ-5-4  gr0023  . . . . Stata tip 27: Classifying data points on scatter plots
        . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .  N. J. Cox
        Q4/05  SJ 5(4):604--606                                (no commands)
        tips for using separate, gray-scale gradation, and text
        characters as class symbols to classify data points on
        a scatter plot

Nick 
n.j.cox@durham.ac.uk 

Nikolaos Pandis
 
In Stata 12, I am using the following commands:

twoway (line moment rotation, by(brackettype)) // moment and rotation continuous and brackettype has 4 levels
 
I like to have all graphs in one plot as shown below but somehow I cannot get on the legend below the x-axis to show the levels of brackettype. It shows "brackettype" for all 4 different color lines. If I use "lfit" instead of "line" it shows lfit instead of brackettype.

twoway (line moment rotation if brackettype==1) ||(line moment rotation if brackettype==2) ||(line moment rotation if brackettype==3) ||(line moment rotation if brackettype==4)
 
Any advise would be appreciated.

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/