Bookmark and Share

Notice: On March 31, it was announced that Statalist is moving from an email list to a forum. The old list will shut down at the end of May, and its replacement, statalist.org is already up and running.


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: st: error 506 (matrix not positive definite) when bootstrapping eigenvalue after one-way manova


From   Austin Nichols <austinnichols@gmail.com>
To   statalist@hsphsun2.harvard.edu
Subject   Re: st: error 506 (matrix not positive definite) when bootstrapping eigenvalue after one-way manova
Date   Tue, 14 Jun 2011 11:08:37 -0400

Carlo Lazzaro <carlo.lazzaro@tin.it>:
It's not clear what your code is aiming at, but maybe this will help:

clear all
sysuse auto
prog ev, eclass
 version 11.2
 if replay() {
  syntax [anything] [, Level(real 95) ]
  eret di, level(`level')
  }
 else {
  qui manova price mpg=`0'
  tempvar e
  tempname ev
  g byte `e'=e(sample)
  mat `ev'=e(eigvals_m)
  eret clear
  eret post `ev', esample(`e')
  eret local cmd "ev"
  }
end
ev foreign rep78
eret di
bs, r(100) seed(1):ev foreign rep78


On Tue, Jun 14, 2011 at 9:19 AM, Carlo Lazzaro <carlo.lazzaro@tin.it> wrote:
> Dear Statalisters,
> before bootstrapping eigenvalue after one-way manova using auto.dta and
> Stata 9.2/SE, I imposed the equality of the means in price and mpg for both
> foreign and domestic cars.
> When I invoked bootstrap, error message r(506) related to model term foreign
> appeared.
> Can anybody please give me some hint about the reason of this drawback and
> how to work it around?
> Thanks a lot for your kindness and for your time.
> Kindest Regards,
> Carlo
> ------------code begins-----------------------
> use "C:\Programmi\Stata9\ado\base\a\auto.dta"
> manova price mpg=foreign
> svmat double c, name(eigen_m)
> scalar sctr=trace(c)
> by foreign, sort: sum price
> sum price if foreign==0, meanonly
> replace price=price-r(mean)+6384.682 if foreign==0
> sum price if foreign==1, meanonly
> replace price=price-r(mean)+6384.682 if foreign==1
> by foreign, sort: sum  mpg
> sum  mpg if foreign==0, meanonly
> replace  mpg= mpg-r(mean)+24.77273 if foreign==0
> sum  mpg if foreign==1, meanonly
> replace  mpg= mpg-r(mean)+24.77273 if foreign==1
> bootstrap trace(c), reps(10000) nodots strata(foreign) bca seed(12345) :
> manova price mpg=foreign
> failure for model term foreign
> an error occurred when bootstrap executed manova
> r(506);
> ------------code ends-----------------------

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/


© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   Site index