# RE: st: Proportion Meta-Analysis

 From "b. water" To Subject RE: st: Proportion Meta-Analysis Date Mon, 5 Oct 2009 20:52:20 +0000

```hi paul,

nicola orsini (from karolinska institute) provided me with this back in 2005 (i used (and still do) stata 8.2, but should not make a difference if you are using stata 10). once you get the hang of it, you can adapt it to problem at hand:

// suppose you have 4 studies
clear
input study cases total
1 20 1000
2 40 5000
3 30 1500
4 25 3300
end
gen p = .
gen se = .
// get proportions and std errors
forv i =1(1)4 {
cii total[`i'] cases[`i']
qui replace p = r(mean) in `i'
qui replace se = r(se) in `i'
}
// get the inverse variance-weighted proportion
// use the official Stata -vwls- command
gen cons =1
vwls p cons, sd(se)
// use the user written -metan- command
// for fixed-effects meta-analysis
metan p se, nograph fixed
// for random-effects meta-analysis
metan p se, nograph random

hth,
bw

----------------------------------------
> Date: Fri, 2 Oct 2009 16:37:33 -0400
> From: preiter@email.unc.edu
> To: statalist@hsphsun2.harvard.edu
> Subject: st: Proportion Meta-Analysis
>
> I am working on a meta-analysis where the outcome of interest is the
> percentage of couples who share the same trait. So, for each included
> study, I have the number of concordant couples (both have the trait)
> and am dividing it by the total number of couples. Is there anyway
> that Stata can do this type of proportion meta-analysis and produce an
> accompanying forest plot? I know Stata is capable of meta-analyses
> type. Thanks.
>
> Paul Reiter
> *
> * For searches and help try:
> * http://www.stata.com/help.cgi?search
> * http://www.stata.com/support/statalist/faq
> * http://www.ats.ucla.edu/stat/stata/
_________________________________________________________________
Hotmail: Trusted email with powerful SPAM protection.
http://clk.atdmt.com/GBL/go/177141665/direct/01/
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/
```