Statalist


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

st: AW: Heckman Selection Rule


From   "Martin Weiss" <martin.weiss1@gmx.de>
To   <statalist@hsphsun2.harvard.edu>
Subject   st: AW: Heckman Selection Rule
Date   Tue, 25 Aug 2009 11:37:28 +0200

<>


You may want to add a little background to your question (why do you want to
do this?), but my feeling is that 

(1) the change in the inequality sign in the selection equation merely
changes the sign of the components of "g" (and the estimate of "rho")

(2) the constant that you want on the RHS will be absorbed into the constant
that -heckman- adds by default to the selection equation. Note that there is
a separate -noconstant- option for it in the -heckman- command...


Bottom line: The outcome equation - in which interest ultimately rests - is
unchanged...


***
vers 10.1

clear*
set obs 10000

//correlation
loc co 0.7

//draw errors
//correlation as in local `co'
matrix input correl = /* 
 */  (1,`co' \ `co',1)
 
drawnorm u1 u2, /* 
 */ corr(correl) /* 
 */ cstorage(full)

//covariates
gen x1=rnormal()  
gen x2=runiform()
gen x3=rchi2(4)

//outcome equation
gen y=2+3*x1+ 4*x3+u1

//selection equation
replace y= . if /* 
 */ -1+2*x2+x1+u2<0
 
heckman y x1 x3 ,/* 
 */ select(x1 x2)/* 
 */  nolog two
 
est store heck


//next round
drop y 

//_new_ outcome equation
gen y=2+3*x1+4*x3+u1

//_new_ selection equation
//Constant on RHS and changed
//inequality sign

replace y= . if /* 
 */ -1+2*x2+x1+u2>3
 
heckman y x1 x3 ,/* 
 */ select(x1 x2)/* 
 */  nolog two

est table heck .
***


HTH
Martin


-----Ursprüngliche Nachricht-----
Von: owner-statalist@hsphsun2.harvard.edu
[mailto:owner-statalist@hsphsun2.harvard.edu] Im Auftrag von mtavoni
Gesendet: Dienstag, 25. August 2009 00:08
An: statalist@hsphsun2.harvard.edu
Betreff: st: Heckman Selection Rule

Dear all,

a quick question on sample selection estimation. In Heckman, STATA 
estimates the parameters in the model:

        (regression equation: y is depvar, x is varlist)
        y = xb + u_1

        (selection equation: Z is varlist_s)
        y observed if Zg + u_2 > 0


What if I want to change the rule for the selection equation to something
like: 

  y observed if Zg + u_2 < Constant


thanks for helping out.

cheers
max

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/


*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index