Statalist


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: AW: st: AW: beta coefficients for interaction terms


From   Maarten buis <maartenbuis@yahoo.co.uk>
To   statalist@hsphsun2.harvard.edu
Subject   Re: AW: st: AW: beta coefficients for interaction terms
Date   Tue, 21 Apr 2009 14:49:30 +0000 (GMT)

--- On Tue, 21/4/09, lschoele@rumms.uni-mannheim.de wrote:
> Without having iteraction terms, as far as I know you have
> to coed -regress, beta- to get the standardised beta 
> coefficients, so you can  tell which variable has the 
> biggest effect.

With interactions you have to very precise about what you 
exactly want. The whole point of an interaction is that 
the effect of a variable is allowed to change when 
another variable changes. So the question which variable 
has the bigger effect now has multiple answers. 

The way forward is to go back to your substantive problem
and try to figure out what it is exactly what you want to
know, and derive your interaction term and standardizations
from that. 

One way that could make sense is to present the difference
between standardized effects for different values of both
variables in a graph like in the example below:

*------------------------ begin example -------------------
sysuse auto, clear
local vlist "price mpg rep78"
foreach var of varlist `vlist' {
	sum `var'
	qui gen double z_`var' = (`var' - r(mean))/r(sd)
}
gen z_mpgXz_rep78 = z_mpg*z_rep78


reg z_price z_mpg z_rep78 z_mpgXz_rep78

gen effdif0 = _b[z_mpg] + _b[z_mpgXz_rep78]* z_mpg - ///
              (_b[z_rep78])

gen effdif_2 = _b[z_mpg] + _b[z_mpgXz_rep78]* z_mpg - ///
              (_b[z_rep78] + _b[z_mpgXz_rep78]*-2)

gen effdif2 = _b[z_mpg] + _b[z_mpgXz_rep78]* z_mpg - ///
              (_b[z_rep78] + _b[z_mpgXz_rep78]*2)

twoway line effdif_2 effdif0 effdif2 mpg, sort ///
   ytitle("difference in standardized effects" ///
          "of mileage and repair status")      ///
   legend(order(1 "z_rep78 = -2"               ///
                2 "z_rep78 = 0"                ///
                3 "z_rep78 = 2"))              ///
   yline(0)                                    
*------------------- end example --------------------------

Hope this helps,
Maarten

-----------------------------------------
Maarten L. Buis
Institut fuer Soziologie
Universitaet Tuebingen
Wilhelmstrasse 36
72074 Tuebingen
Germany

http://home.fsw.vu.nl/m.buis/
-----------------------------------------




      

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index