Statalist


[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

st: RE: combining frequency tables


From   "Nick Cox" <[email protected]>
To   <[email protected]>
Subject   st: RE: combining frequency tables
Date   Mon, 23 Feb 2009 16:01:48 -0000

As I've said before, there's no virtue in simple questions. We want
_interesting_ questions! 

This seems to be a question about Excel to the extent that it raises
another question: Can't you do that in Excel if that's a tool of choice?
(No idea from me.) 

But there are also many Stata answers. -findit mdesc- reveals that it is
a program by Rose Anne Medeiros, who once wrote a program called -njc-,
for which I am not responsible. Here is a matrix version of her program,
for which she is not responsible. 

*! mmdesc 1.0 NJC 23 February 2009 
* mdesc 1.0 RAM 18 JULY 2008
* Returns a table with number missing, total, and missing/total
program mmdesc, rclass byable(recall)
version 8 
syntax [varlist] [if] [in]
tempvar touse
mark `touse' `if' `in'
local nvars : word count `varlist' 
tempname matrix 
matrix `matrix' = J(`nvars', 3, .) 
local i = 1 
quietly foreach var of local varlist {
	count if missing(`var') & `touse' 
	matrix `matrix'[`i', 1] = r(N) 
	count if `touse'
	matrix `matrix'[`i', 2] = r(N) 
	matrix `matrix'[`i', 3] = `matrix'[`i',1] / `matrix'[`i',2] 
	local ++i  
}
matrix rownames `matrix' = `varlist'                     
matrix colnames `matrix' = Missing Total Missing/Total 
matrix list `matrix', noheader 
return matrix table = `matrix' 
end

Once you run this, you can save its results by e.g. 

mat A = r(table) 

... 

mat B = r(table) 

...

mat C = A + B 


Nick 
[email protected] 

Shehzad Ali

Another (perhaps) simple question: is it possible to add different 
frequency tables together to form a combined single table in Excel?

I have two group variables (say, var1: type of treatment; and var2: time

point of observation) and 5 use variables. So an observation would be
for 
treatment A at time point 1. I want to know the number of missing values

for each use variable for each treatment group and each time point. Also

for each use variable there are 'if' conditions, so I can't do the 
frequency count in one go. Here is what I am doing using a user written 
programme -mdesc- or -missing-:

by treatment timpoint: mdesc use1 if (condition1 condition2)

by treatment timpoint: mdesc use2 if (condition3 condition4)

and so on. 

 
Now I want to combine all these counts for all timepoints and treatment 
groups to get a single table that I can export to Excel. Is there any
way I 
could do that?

*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2024 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index