Statalist


[Date Prev][Date Next][Thread Prev][Thread Next][Date index][Thread index]

Re: st: displaying/summarizing covariate balance


From   "Austin Nichols" <austinnichols@gmail.com>
To   statalist@hsphsun2.harvard.edu
Subject   Re: st: displaying/summarizing covariate balance
Date   Fri, 19 Sep 2008 12:26:30 -0400

Pierre--
I should have also mentioned that you can also use these models to
reweight the data so that the means of all x* variables are the same
across the two groups (note that matching is also a form of
reweighting), as alluded to in SJ7(4):
http://www.stata-journal.com/article.html?article=st0136

For example:

use http://fmwww.bc.edu/ec-p/data/wooldridge/card, clear
loc x "age exper* black smsa66 reg662-reg669"
g m=marr==1
qui hotelling `x', by(m)
loc F=(r(N)-r(k)-1)/(r(N)-2)/r(k)*r(T2)
loc p=Ftail(r(k),r(df),`F')
di "F=" `F' ", p=" `p'
qui reg m `x'
di "F=" e(F) ", p=" Ftail(e(df_m),e(df_r),e(F))
qui logit m `x'
predict p
g rwt=cond(m,1-p,p)
qui reg m `x' [aw=rwt]
di "F=" e(F) ", p=" Ftail(e(df_m),e(df_r),e(F))

*to put the -hotelling- output into a table, I suggest -estout- from SSC:

est clear
qui reg id `x' if m==0
est sto C
estadd summ: *
tempfile C
est save `C'
est clear
qui reg id `x' if m==1
est sto T
estadd summ: *
estadd scalar Ftest `F'
est use `C'
est sto C
esttab C T, main(mean) aux(sd) scalar(Ftest) nodep nostar nocons

With the -rtf- option on -esttab- you can write to a file with the
.doc extension and double-click to open in MS Word, and with the -tex-
option you can write a LaTeX table.

On Fri, Sep 19, 2008 at 10:42 AM, Austin Nichols
<austinnichols@gmail.com> wrote:
> Pierre Azoulay <pierre.azoulay@gmail.com>:
> You are using -nnmatch- from SSC, I take it? Just use the same tests
> as used for testing balance of (pretreatment) covariates under random
> assignment: if treatment is a var tr taking on values 0/1 and
> covariates are x* then
>  hotelling x*, by(tr)
> and
>  reg tr x*
> give the same F-test for differences in means (add ,robust to the
> latter to relax assumptions about equal variance, or use logit or
> probit for alternative discriminants).  Or did you want to compare the
> whole distribution of values for all x* (in which case a bunch of
> kernel density graphs are in order)?
>
> On Fri, Sep 19, 2008 at 10:18 AM, Pierre Azoulay
> <pierre.azoulay@gmail.com> wrote:
>> Dear Statalisters,
>>
>> I am doing a very simple nearest-neighbor matching exercise for a
>> paper of mine, and I would be interested in suggestiopns on how best
>> to summarize and/or display covariate balance among the matched units,
>> if possible with code examples. A search on "covariate balance" in
>> stata list did not reveal anything enlightening.
>
*
*   For searches and help try:
*   http://www.stata.com/help.cgi?search
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index