Statalist


[Date Prev][Date Next][Thread Prev][Thread Next][Date index][Thread index]

Re: Rép. : Re: st: Interpretation of -mfx-


From   Maarten buis <maartenbuis@yahoo.co.uk>
To   statalist@hsphsun2.harvard.edu
Subject   Re: Rép. : Re: st: Interpretation of -mfx-
Date   Thu, 19 Jun 2008 08:27:53 +0100 (BST)

--- Herve STOLOWY <stolowy@hec.fr> wrote:
> I use the auto file and make a logit regression followed by mfx.
> 
> sysuse auto
> logit  foreign mpg weight price
> mfx
>
> Here is my question: in the logit ouput, the coefficients on weight
> and price are significant. In the mfx output, the corresponding
> coefficients of dy/dx are NOT significant. How should I interpret
> this result?

-mfx- summarizes a non-linear relationship using the slope when all
explanatory variables have their mean value. As can be seen in the
graph  created in the example below, the slope is steepest (effect is
highest) on the right, which is also where most of the data is. However
because the distribution is right skewed, the mean is to to right of
where most of the data is and where the effect happens to be strongest.
The log odds ratio also summarizes the slope with a single number, but
this number is independent of at what value of mpg it is evaluated, so
it is not subjected to this problem.

An alternative is to compute the marginal effect for each individual,
and than compute the average of these marginal effects. This is close
to what is done in Tamas Bartus' -margeff- package, downloadable from 
-ssc-. Except that he uses partial effects instead of marginal effect.
To quote from his helpfile: "Partial effects are discrete partial
changes in the quantities of interest as the variable under study
increases by the unit of measurement.  For dummy variables (variables
coded 0/1) and count  variables, unit of measurement is 1. This partial
change approach eases computations, and approximates very well the
partial changes calculated using the classic marginal effects
approach."

Hope this helps,
Maarten

*---------- begin example ----------------
set more off
sysuse auto, clear
logit  foreign mpg weight price
mfx
adjust  weight price, by(mpg) pr gen(pr)
sum mpg if e(sample), meanonly
twoway line pr mpg, sort       ///
   xline(`r(mean)')            ///
   ysca(alt)                   ///
   xsca(alt range(10 43))      ///
   saving(pr, replace)
twoway histogram mpg, fraction ///
   xlab(10(10)40)              ///
   ysca(alt reverse)           ///
   xscale(range(10 44))        ///
   saving(hy, replace)         ///    
   fysize(25)
graph combine pr.gph hy.gph,   ///
   cols(1)                     ///
   imargin(0 0 0 0)            ///
   graphregion(margin(l=22 r=22)) 
margeff
*---------- end example ------------------
(For more on how to use examples I sent to the Statalist, see
http://home.fsw.vu.nl/m.buis/stata/exampleFAQ.html )

-----------------------------------------
Maarten L. Buis
Department of Social Research Methodology
Vrije Universiteit Amsterdam
Boelelaan 1081
1081 HV Amsterdam
The Netherlands

visiting address:
Buitenveldertselaan 3 (Metropolitan), room Z434

+31 20 5986715

http://home.fsw.vu.nl/m.buis/
-----------------------------------------


      __________________________________________________________
Sent from Yahoo! Mail.
A Smarter Email http://uk.docs.yahoo.com/nowyoucan.html
*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index