Statalist


[Date Prev][Date Next][Thread Prev][Thread Next][Date index][Thread index]

Re: st: right censoring of dependent and independent variable


From   Maarten buis <[email protected]>
To   [email protected]
Subject   Re: st: right censoring of dependent and independent variable
Date   Thu, 29 May 2008 13:43:58 +0100 (BST)

--- Garry Anderson <[email protected]> wrote:
> I have data where both the dependent and independent variable are
> right censored and continuous. Although intreg, cnreg or tobit can
> handle censoring of the dependent variable, they do not seem to allow
> censoring of the independent variable. Both the instruments can only
> measure to a maximum value, 30% of values are right censored on the Y
> variable and 15% on the X variable. 
>  
> I would welcome suggestions as to how to incorporate right censoring
> of the independent variable?

In the graph below you can see that selection on the x variable is much
less of a problem than selection on the y variable. A part of the data
is turned into influential outliers, by selecting on the y. In the
example it is the upper right part of the observed values that pull the
regression line down. However, the same does not happen when you select
on x. With regression you model the mean of y conditional on x, the
fact that you don't observe all values of x, is unfortunate (loss of
power) but not disastrous. Things become obviously more complicated
when you are interested in any non-linearities in the effect of x. 

Hope this helps,
Maarten

*----------------------- begin example ------------------------
clear
set seed 12345
matrix C = (1, .5 \ .5, 1)
drawnorm x y, n(1000) corr(C)
twoway scatter y x if x < 1, aspect(1) xline(1) || ///
       scatter y x if x >= 1, msymbol(oh) mcolor(gs10) || ///
       lfit y x , lpattern(solid) lcolor(green) || ///
       lfit y x if x < 1, lpattern(solid) lcolor(red) ///
       title(selection on x) name(x, replace) ///
       legend(order( 1 "observed" ///
                     2 "censored" ///
                     3 "true"     ///
                     4 "estimated") ///
              rows(2))
 
    

twoway scatter y x if y < 1, aspect(1) yline(1) || ///
       scatter y x if y >= 1, msymbol(oh) mcolor(gs10) || ///
       lfit y x , lpattern(solid) lcolor(green) || ///
       lfit y x if y < 1, lpattern(solid) lcolor(red) ///
       title(selection on y) name(y, replace) ///
       legend(order( 1 "observed" ///
                     2 "censored" ///
                     3 "true"     ///
                     4 "estimated") ///
              rows(2) colfirst)


grc1leg y x
*------------------------ end example ---------------------------
(For more on how to use examples I sent to the Statalist, see
http://home.fsw.vu.nl/m.buis/stata/exampleFAQ.html )

For this example to run you need to download the -grc1leg- package,
see: -findit grc1leg-.


-----------------------------------------
Maarten L. Buis
Department of Social Research Methodology
Vrije Universiteit Amsterdam
Boelelaan 1081
1081 HV Amsterdam
The Netherlands

visiting address:
Buitenveldertselaan 3 (Metropolitan), room Z434

+31 20 5986715

http://home.fsw.vu.nl/m.buis/
-----------------------------------------


      __________________________________________________________
Sent from Yahoo! Mail.
A Smarter Email http://uk.docs.yahoo.com/nowyoucan.html
*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2024 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index