Statalist


[Date Prev][Date Next][Thread Prev][Thread Next][Date index][Thread index]

Re: st: xtreg, fe cluster dfadj option


From   "Austin Nichols" <austinnichols@gmail.com>
To   statalist@hsphsun2.harvard.edu
Subject   Re: st: xtreg, fe cluster dfadj option
Date   Tue, 12 Feb 2008 11:20:33 -0500

Ilaria Tucci <ilale78@yahoo.it>:
See
http://www.stata.com/statalist/archive/2006-12/msg00867.html
and its references, or try

webuse nlswork, clear
est drop _all
xtreg ln_w age ttl_exp tenure, fe
est sto xtreg
areg ln_w age ttl_exp tenure, abs(`g')
est sto areg
xtreg ln_w age ttl_exp tenure, fe vce(r)
est sto xtregr
areg ln_w age ttl_exp tenure, abs(`g') vce(r)
est sto aregr
xtreg ln_w age ttl_exp tenure, fe vce(cl id)
est sto xtregc
areg ln_w age ttl_exp tenure, abs(`g') vce(cl id)
est sto aregc
xtreg ln_w age ttl_exp tenure, fe vce(cl id) dfadj
est sto xtregcdf
ssc inst estout
esttab *

In short, -areg- is the same as -xtreg, fe- or including indicators
for each panel in a pooled OLS regression except when using
cluster-robust SEs.  In that case, -areg- will give you standard
errors that are bigger by a factor of the square root of N/(N-M).  If
you regard the M fixed effects as nuisance parameters, and your
asymptotic justification for the cluster-robust SE requires M close to
infinity, multiplying by the square root of N/(N-M) will make your SEs
too big.  If N=2M for example, and M is large enough to justify the
use of the cluster-robust SE, the -areg- VCE will give you variance
estimates that are twice as big as they "should" be.  If panels are
not nested within clusters and there are few obs per panel, though, or
you care about the FE estimates, then you want the larger standard
errors.

See also the manual entry [XT] xtreg.

On Feb 8, 2008 3:58 PM, Ilaria Tucci <ilale78@yahoo.it> wrote:
> Dear all
>
> Hi I have a question concerning the cluster option with xtreg, fe. I saw that in stata 9.0 the option cluster was correcting for intragroup correlation and for the within transoform, while in stata 9.2 the option cluster adjusts only for intragroup correlation, unless is specified the command dfadj. I'm not sure to have understood which is the meaning of the adjustment for the within transformation (dfadj, that is seldom used) and, overall, when it is the case to be applied.
> Can anyone help me to understand it or suggest me something I can read about??
>
> The data I use are individual data for which I adjust the standard errors (with the cluster option) for heteroskedasticy and autocorrelation by the regions they live in.
>
> Thank you
> Ilaria
*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index