Statalist The Stata Listserver


[Date Prev][Date Next][Thread Prev][Thread Next][Date index][Thread index]

Re: st: xtlogit - odds ratios for continuous predictors


From   "Austin Nichols" <[email protected]>
To   [email protected]
Subject   Re: st: xtlogit - odds ratios for continuous predictors
Date   Wed, 9 May 2007 16:15:12 -0400

S�ren--
As I understand it, you want to report an odds ratio, but one where a
one-unit change in X corresponds to something you can make sense of.
Why don't you redefine your X by multiplying by 10 or some other
number that makes sense?

webuse nlswork, clear
bys id (year): drop if _n<_N
gen pcunem=wks_u/(wks_ue+wks_w)
logit c_city pcunem, or
gen wksunem=pcunem*52
logit c_city wksunem, or

The first uses percent of year unemployed as X, the second uses weeks
unemployed as X.  Clearly, it's easier to think about a one-unit
change in the latter.

For your data, you might think about two observations that represent
an interesting comparison, and multiply your X by the inverse of the
difference between those two.  E.g. suppose efrag in France is 0.35
and in Germany is 0.55, and you multiply efrag by 1/(.55-.35)=5.  You
could also summarize efrag and divide it by its standard deviation, I
guess, to interpret a one-unit change in X as an increase of one SD.

su pcu
g spc=pcu/r(sd)
su wksu
g swk=wksu/r(sd)
logit c_city spc, or nolog
logit c_city swk, or nolog

A better way is probably to graph predicted probabilities over the
whole range, however.  See http://www.indiana.edu/~jslsoc/spost.htm
for more...

logit c_city pcunem, or nolog
predict p
locpoly p pcu, noscatter name(p)
logit c_city wksunem, or nolog
predict w
locpoly w wksu, noscatter name(w)

Examples rewritten for -xtlogit- (takes longer, point is the same):
webuse nlswork, clear
tsset id year
gen pcunem=wks_u/(wks_ue+wks_w)
xtlogit c_city pcunem, or
predict p
gen wksunem=pcunem*52
xtlogit c_city wksunem, or
predict w
su pcu
g spc=pcu/r(sd)
su wksu
g swk=wksu/r(sd)
xtlogit c_city spc, or nolog
xtlogit c_city swk, or nolog
locpoly p pcu, noscatter name(p)
locpoly w wksu, noscatter name(w)


On 5/9/07, S�ren Mayland <[email protected]> wrote:
Hi,

I'm using xtlogit to model a two level (country-individual) model.
I am probably in way over my head, as I am using it in my Political Science
bachleor, and has been using SPSS until last week..  ..anyway:
One of my predictores at country level are a level of ethnic fragmentation
which ranges between 0,2 and about 0,8.
Basicly what I need is the best way to report my results.
So far Im settling for odds ratio, but this makes the results of the above
predictor to complex to report.
The only solution I have found this far is standardizing the variable. (hov
do I find the standard deviation for my predictor in xtlogit Stata?)

*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2024 StataCorp LLC   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index