Stata The Stata listserver
[Date Prev][Date Next][Thread Prev][Thread Next][Date index][Thread index]

Re: st: RE: radial axis to Galbraith plot


From   "Ben Dwamena" <bdwamena@med.umich.edu>
To   <n.j.cox@durham.ac.uk>, <statalist@hsphsun2.harvard.edu>
Subject   Re: st: RE: radial axis to Galbraith plot
Date   Wed, 16 Nov 2005 18:07:43 -0500

Thanks Nick .
With this version 8.2  rendition of -galbr- can circscatter be incorporated to provide the cicular axis?
Ben

Ben Adarkwa Dwamena, MD

Assistant Professor of  Radiology
Division of Nuclear Medicine
Department of Radiology
University of Michigan Medical School
1500 E. Medical Center Drive
B1  G505   University  Hospital
Ann Arbor, MI 48109-0028

bdwamena@umich.edu

http://sitemaker.umich.edu/metadiagnosis



Staff Physician
D748 Nuclear Medicine Service (115), 
VA Ann Arbor Health Care System
2215 Fuller Road
Ann Arbor, MI 48105
734-761-7886 Phone
734-761-5229 Fax


>>> n.j.cox@durham.ac.uk 11/16/05 5:55 PM >>>
My guess is that a circular scale is programmable
here, but that there is no way that any existing 
official Stata call will produce what you want. 

-galbr- doesn't seem to have been updated 
since STB-56. The following is a fairly free
translation that should not be blamed on Aurelio
Tobias. It doesn't bear a circular scale. 

*! galbr8 NJC 3.0.0 16 November 2005
*! galbr AT 2.0 Marc 2000     (STB-56: sbe20.1)
*! galbr AT 1.15 June/October 1997
program galbr8 
	version 8.2
	syntax varlist(min=2 max=2 numeric) [if] [in] ///
	[, id(varname) scatter(str asis) fitted(str asis) ///
	upper(str asis) lower(str asis) *]
	
	tokenize `varlist'
	args E SE 
	
	quietly { 
		marksample touse 
		count if `touse' 
		if r(N) == 0 error 2000 

		tempvar x y 
		gen `x' = 1 / `SE'
		su `x' if `touse', meanonly 
		local maxx = r(max) 
		gen `y' = `E'/`SE' 
		reg `y' `x' if `touse', noconstant
	}	

	if "`id'" != "" local show "ms(none) mla(`id') mlabpos(0)"
		
	scatter `y' `x' if `touse', `show' `scatter' || /// 
	function fitted = _b[`x'] * x, ra(0 `maxx') `fitted' || ///  
	function upper = 2 + _b[`x'] * x, ra(0 `maxx') ///
		clp(dash) clc(green) `upper' || ///  
	function lower = -2 + _b[`x'] * x, ra(0 `maxx') ///
		clp(dash) clc(green) `lower' || ///  
	, legend(order(2 3 "upper limit" 4 "lower limit") row(1)) ///  
		yti(b / se(b)) xti(1 / se(b)) `options' 
end




Nick 
n.j.cox@durham.ac.uk 

> -----Original Message-----
> From: owner-statalist@hsphsun2.harvard.edu
> [mailto:owner-statalist@hsphsun2.harvard.edu]On Behalf Of Ben Dwamena
> Sent: 16 November 2005 21:25
> To: statalist@hsphsun2.harvard.edu
> Subject: st: radial axis to Galbraith plot
> 
> 
> Dear Statalisters
> Does anyone know how stata may be used to produce yaxis(2)  
> circular scale   in a Galbraith plot(i.e. see Tobias' galbr 
> command for vi suographically investigating heterogeneity in 
> meta-analysis) which incorporates a scatter plot of 
> standardized effect size on yaxis(1) versus precision on x axis?
> Thanks
> Ben
> 
> 
> 
> **********************************************************
> Electronic Mail is not secure, may not be read every day, and 
> should not be used for urgent or sensitive issues.
> 
> *
> *   For searches and help try:
> *   http://www.stata.com/support/faqs/res/findit.html
> *   http://www.stata.com/support/statalist/faq
> *   http://www.ats.ucla.edu/stat/stata/
> 

*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



**********************************************************
Electronic Mail is not secure, may not be read every day, and should not be used for urgent or sensitive issues.

*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index