Stata The Stata listserver
[Date Prev][Date Next][Thread Prev][Thread Next][Date index][Thread index]

Re: st: Modelling two binary outcomes that are not mutually exclusive


From   Joseph Coveney <jcoveney@bigplanet.com>
To   Statalist <statalist@hsphsun2.harvard.edu>
Subject   Re: st: Modelling two binary outcomes that are not mutually exclusive
Date   Sun, 28 Nov 2004 01:31:11 +0900

Ronán Conroy wrote:

I have two binary outcomes, measured in a patient population (anxiety 
and depression). For various reasons, I suspect that a number of patient 
characteristics predict depression but not anxiety.

If the two diagnoses were mutually exclusive, all would be well. I could 
use multinomial logistic regression and compare the coefficients. 
However, there is about a 20% overlap. Is this a Known Problem? I could 
model the overlap category as a third outcome, and show that the 
coefficients were similar to those for depression alone and different to 
those for anxiety alone, but this is slicing the sample a little thin - 
there are just 8 people with both disorders. (This approach actually 
works, sort of, given the small numbers, so I'm on the right track from 
the theory point of view.)

Any suggestions out there?

--------------------------------------------------------------------------------

Would -biprobit- (along the lines of Mark Schaffer's suggestion), or -xtprobit- 
lend any help?

As an alternative, would formally modeling as a bivariate binomial regression 
using -gllamm- (two random effects, one for each outcome, ŕ la Van 
Houwelingen's bivariate approach to meta-analysis) help?

Joseph Coveney

clear
set more off
drawnorm y1 x1 x2, mean(0 0 0) ///
  sd(1 1 1) corr(1 0.7 0.7 \ 0.7 1 0.7 \ 0.7 0.7 1) ///
  n(200) seed(`=date("2004-11-28", "ymd")')
generate byte y0 = uniform() > 0.5 // y0, Anxiety
replace y1 = y1 > 0  // y1, Depression
compress
pwcorr
biprobit y0 y1 x1 x2
// It shows that y1 is predicted and not y0
generate int pid = _n
reshape long y, i(pid) j(dep)
xi: xtprobit y i.dep*x1 i.dep*x2, i(pid) re
// The dependent-variable-by-predictor interaction terms 
// indicate that one is predicted and not the other (given the
// necessary assumptions)
exit



*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index