Stata The Stata listserver
[Date Prev][Date Next][Thread Prev][Thread Next][Date index][Thread index]

st: Re: Serial Correlation in system estimator


From   "Scott Merryman" <smerryman@kc.rr.com>
To   <statalist@hsphsun2.harvard.edu>
Subject   st: Re: Serial Correlation in system estimator
Date   Tue, 2 Mar 2004 21:00:27 -0600

Jan,

I believe you can.  The basic idea to use -xtgls- with individual intercepts and
slope variables and with cross-sectional correlation (as in SUR) and
panel-specific AR(1) (as in -prais-).

Here is an example and comparison of -xtgls, p(c)- to -sureg-

webuse grunfeld, clear
tab com, gen(D)
foreach var1 of varlist D* {
    foreach var2 of varlist mvalue kstock {
        gen `var1'`var2' = `var1'*`var2'
        }
 }

aorder

xtgls invest D*, nocons  p(c) corr(psar1)

*
*Compare to xtgls, p(c) to SUR
*

xtgls invest D*, nocons p(c)

keep invest mval kstock year com
reshape wide invest mval kstock, i(year) j(com)

forv i=1/10 {
  local rhs "`rhs' ( invest`i' mvalue`i' kstock`i') "
   }

sureg `rhs'

I hope this helps,
Scott

----- Original Message ----- 
From: "Jan Pettersson" <jan.pettersson@ne.su.se>
To: <statalist@hsphsun2.harvard.edu>
Sent: Friday, February 27, 2004 8:39 AM
Subject: st: Serial Correlation in system estimator


> Dear all,
>
> Does anyone know any (preferably easy) way to correct for serial correlation
> (such as newey or prais) when a system is estimated?
> I am running SUREG.
>
> Thanks in advance,
> Jan
>

*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index