Stata The Stata listserver
[Date Prev][Date Next][Thread Prev][Thread Next][Date index][Thread index]

st: Re: xtfrontier


From   "Scott Merryman" <smerryman@kc.rr.com>
To   <statalist@hsphsun2.harvard.edu>
Subject   st: Re: xtfrontier
Date   Sun, 21 Dec 2003 21:04:31 -0600

Naveeda,

Suppose you have a translog production function:

Y = b0 + b1Labor + b2Kapital + b3Time + .5[b4Kapital^2 + b5Labor^2 + b6Time^2] +
b7Kapital*Labor + b8Kapital*Time + b9Labor*Time + u_it - v_it

where all output capital and labor are in logs.

The elasticity of output with respect to capital and labor are:

e_k = b2 + b4Kapital + b7Labor + b9Time

e_l = b1 + b5Labor + b7Kapital + b9Time

Returns to Scale is:

RTS = e_k + e_l. If RTS < 1 this indicates decreasing returns to scale; if RTS =
1 this indicates constant returns to scale, and RTS > 1 this indicates
increasing returns to scale.

Technological progress, TP, equals the derivative of the production functions
with respect to time:

TP = b3 + b6Time + b8Kapital + b9Labor

Technological progress is positive, zero, or negative depending if it shifts the
frontier up, leaves it unchanged or shifts it down.

Change in Technical Efficiency, TE, is the derivative of the negative of the
inefficiency measure with respect to time:

TE=  -du_it/dt = eta*u_it

Technical efficiency is positive, zero, or negative depending if technical
inefficiency declines, remains unchanged, or increases over time.  TE can be
thought of as the rate at which producers move towards or away from the frontier
(which itself maybe moving).

Growth of Total Factor Productivity, TFP, is the following sum:

TFP = TP + TE + (RTS - 1)[(e_k/RTS)*(change in K) + (e_l/RTS)*(change in L)]

The last term of TFP accounts from the returns of scale.  Increasing K and L by
z% will increase output by more than z% if there is increasing RTS, and by less
than z% if there is decreasing RTS.  If there are constant returns to scale (RTS
= 1) than input changes do not affect TFP.

Of course, if you are estimating a Cobb-Douglas production function the results
above simplify, or if you are estimating production function with more than two
inputs the above results will have to be adjusted.

Below is a simple program to estimate the change in TFP for either a two-factor
Cobb-Douglas or a two-factor translog production function.

I would strongly recommend Kumbhakar and Lovell's "Stochastic Frontier Analysis"
from which the above taken (pages 281 - 287), at least until the Stata Press
book on stochastic frontier models is published.

Hope this helps,
Scott


*!version 1.0.0 Dec 21, 2003 Scott Merryman
program tfp
version 8.2
syntax, Kapital(varname) Labor(varname) Time(varname) [K2(varname) L2(varname)
LT(varname) KT(varname) LK(varname) ///
T2(varname)] Model(str) Input(real)

*input: percentage change in input factors

if "`e(cmd)'" != "xtfrontier" {
  di as err "tfp only works after xtfronier"
  exit 198
 }
if e(model) != "tvd" {
  di as err "tfp only works with the tvd option"
  exit 198
 }

tempvar ek el rts tp u te

if "`model'" == "cobb" {
 scalar `ek' = _b[`kapital']
 scalar `el' = _b[`labor']
 scalar `rts' = `el' + `ek'
 scalar `tp' = _b[`time']
 predict double `u' , u
 gen double `te' = _b[/eta]*`u'
 gen double tfp = `tp' + `te' + (`rts' -1 )*((`el'/`rts')*(`input') +
(`ek'/`rts')*(`input'))
}

if "`model'" == "trans" {
 gen double `ek' = _b[`kapital'] + _b[`k2']*`kapital' + _b[`lk']*`labor' +
_b[`kt']*`time'
 gen double `el' = _b[`labor'] + _b[`l2']*`labor' + _b[`lk']*`kapital' +
_b[`lt']*`time'
 gen double `rts' = `el' + `ek'

 gen double `tp' = _b[`time'] + _b[`kt']*`kapital' + _b[`lt']*`labor' +
_b[`t2']*`time'
 predict double `u' , u
 gen double `te' = _b[/eta]*`u'
 gen double tfp = `tp' + `te' + (`rts' -1 )*((`el'/`rts')*(`input') +
(`ek'/`rts')*(`input'))
}
end



----- Original Message ----- 
From: "naveeda salam" <nomi67@yahoo.com>
To: <statalist@hsphsun2.harvard.edu>
Sent: Thursday, December 18, 2003 9:29 AM
Subject: st: xtfrontier


> Hi,
> i am working with xtfrontier using sectoral level
> data.  xtfrontier is follwing battese coelli(1992)
> time varying parameterisation and hence technical
> efficiency effects can be calculated using this
> command.
> i also want to calculate technical progress to compose
> total factor productivity.  can anyone help , how can
> we do it. in their book 'an introduction to efficiency
> and productivity analysis' tim coelli and  George
> Battese, have mentioned that this can be done from the
> parameters of stocahstic frontier produciton function
> but i am not clear  what is the procedure?
> Can anyone guide in this matter please.
>
> Thank you
> Naveeda
>
>

*
*   For searches and help try:
*   http://www.stata.com/support/faqs/res/findit.html
*   http://www.stata.com/support/statalist/faq
*   http://www.ats.ucla.edu/stat/stata/



© Copyright 1996–2014 StataCorp LP   |   Terms of use   |   Privacy   |   Contact us   |   What's new   |   Site index