Sayer, Bryan
>
> I've just gotten Stata 8 SE installed, and I've run into a
> few questions
> that I'm not finding answers to:
>
> 3. Is there a list (or a way to get a list) for the
> archives at SSC of
> modules that are new or updated for Stata 8?
I tried searching for "Stata 8" on SSC itself, but I
couldn't get much joy. This idea is a little better:
1. quietly call -ssc whatsnew-
2. extract the names of packages revised in last month
3. -ssc desc- on each one.
This is like the newspaper: it doesn't do anything for you
unless you skim through what is printed for what you want.
program sscnewspaper
version 8
tempfile myfile
qui ssc whatsnew, saving(`"`myfile'"') type
tempname in
file open `in' using `"`myfile'"', r
file read `in' line
while r(eof) == 0 {
if index(`"`line'"', "{net") {
local pos = index(reverse(`"`line'"'),":")
local pkg = substr(`"`line'"',-`pos'+1,`pos'-2)
if substr("`pkg'",1,3) != "SSC" {
local pkgs "`pkgs' `pkg'"
}
}
file read `in' line
}
file close `in'
foreach p of local pkgs {
ssc desc `p'
more
}
end
In practice, going back a month misses one trivial
package new for Stata 8, as of today.
Nick
[email protected]
*
* For searches and help try:
* http://www.stata.com/support/faqs/res/findit.html
* http://www.stata.com/support/statalist/faq
* http://www.ats.ucla.edu/stat/stata/
