Here's one quick solution, which just wraps its own display routine
around -summarize-:
prog define mysum
version 7
syntax varlist
di
di "{txt}{ralign 12:Variable} {c |}" _c
di "{ralign 8:Obs}{ralign 12:Mean}{ralign 12:Std. Dev.}"
di "{hline 13}{c +}{hline 32}"
foreach var of local varlist {
qui sum `var'
local vname = abbrev("`var'",12)
di "{txt}{ralign 12:`vname'} {c |}{res}" _c
di %8.0f `r(N)' " " _c
di %9.0g `r(mean)' " " _c
di %9.0g `r(sd)'
}
end
--Nick Winter
-----------------------------------------------------------
Nicholas Winter, Ph.D. P 202.939.5343
Policy Studies Associates F 202.939.5732
1718 Connecticut Avenue, NW [email protected]
Washington, DC 20009-1148 www.policystudies.com
-----------------------------------------------------------
> -----Original Message-----
> From: John GIBSON [mailto:[email protected]]
> Sent: Thursday, September 12, 2002 9:21 AM
> To: [email protected]
> Subject: st: Summarize without Min and Max
>
>
> Dear Listers
>
> I am working on confidential unit record files and my output
> is not allowed to identify individual respondents. This
> prevents using the "Summarize" command when I want means and
> std deviations of my variables, because Max and Min are also
> included and these refer to individual respondents.
>
> While I can use Tabstat it is much less convenient because I
> have to specify the varlist (and using _all fails because
> there are string variables in the dataset).
>
> Does anyone have a version of the Summarize command that
> suppresses the Min and Max?
>
> Thanks.
>
> John Gibson
>
> *
> * For searches and help try:
> * http://www.stata.com/support/faqs/res/findit.html
> * http://www.stata.com/support/statalist/faq
> * http://www.ats.ucla.edu/stat/stata/
>
*
* For searches and help try:
* http://www.stata.com/support/faqs/res/findit.html
* http://www.stata.com/support/statalist/faq
* http://www.ats.ucla.edu/stat/stata/
